ルネサス社製のマイコンRA4M1の「Renesas RA4M1グループ ユーザーズマニュアル ハードウェア編」のp.142の表8.2を見てみましょう．
内部クロックのクロック発生回路の仕様が書かれています．
様々な内部クロックがある中で，よく使いそう(設定できそう)なのは以下の6つくらいです:

• システムクロック（ICLK）:
  用途: CPU/SRAM/Flash/ダイレクトメモリアクセス関連(DTC/DMAC)
  最大周波数: 48MHz
  分周比: 1, 2, 4, 8, 16, 32, 64

• 周辺モジュールクロックA（PCLKA）
  用途:  SPI/GPT(General PWM Timer)バスクロック/その他(SCI/SCE5/CRC)
  最大周波数: 48MHz
  分周比: 1, 2, 4, 8, 16, 32, 64

• 周辺モジュールクロックB（PCLKB）
  用途: DAC12/IIC(I2C)/CAN/その他(SSI/DOC/CAC/AGT/PORG/CTSU)
  最大周波数: 32MHz
  分周比: 1, 2, 4, 8, 16, 32, 64

• 周辺モジュールクロックC（PCLKC）
  用途: ADC14変換クロック
  最大周波数: 64MHz
  分周比: 1, 2, 4, 8, 16, 32, 64

• 周辺モジュールクロックD（PCLKD）
  用途: GPTカウントクロック
  最大周波数: 64MHz
  分周比: 1, 2, 4, 8, 16, 32, 64

• フラッシュインタフェースクロック（FCLK）
  用途: フラッシュインターフェース
  周波数: 1MHz～32MHz
  分周比: 1, 2, 4, 8, 16, 32, 64

この時点で既にA/D変換のクロックは最大64MHzとなっており，最大周波数48MHzよりも大きいことがわかります．
では，次に，Arduino UNO R4のデフォルトの分周比がどうなっているか，調べていきましょう!

SCKDIVCRレジスタのアドレスは「SYSTEM.SCKDIVCR 4001 E020h」でしたね．
この「SYSTEM.SCKDIVCR」を改造していくことで，Arduino IDEからSCKDIVCRレジスタにアクセスすることができます．
すべてのレジスタで試していないので真偽はわかりませんが，きっと他のレジスタでも同じ方法で基本的にはアクセスできるはずです．

1. 「ドット(.)」を「アロー演算子->」に変える
   「SYSTEM->SCKDIVCR」

2. 先頭に「R_」を付ける
   「R_SYSTEM->SCKDIVCR」

以上です!(簡単ですね～)

実際にArduino IDEでSCKDIVCRレジスタの値を確認するソースコードを書いてみましょう．

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  Serial.print("SYSTEM.SCKDIVCR (HEX) = ");
  Serial.println(R_SYSTEM->SCKDIVCR, HEX);
}

void loop() {
  // put your main code here, to run repeatedly:
}

結果は，16進数で「10010100」でした．
これを2進数に直すと「0  001  0  000  00000001  0  000  0  001  0  000  0  000」となります．
この値に対してルネサス社製のマイコンRA4M1の「マニュアルーハードウェア」のp.146のSCKDIVCRレジスターの配列の値に書き直すと

• FCLK( FCK[2:0] ) : 0  0  1  →  1/2分周比

• ICLK ( ICK[2:0] ) : 0  0  0   →  1/1分周比

• PCLKA ( PCKA[2:0] ) : 0  0  0  →  1/1分周比

• PCLKB ( PCKB[2:0] ) : 0  0  1  →  1/2分周比

• PCLKC ( PCKC[2:0] ) : 0  0  0  →  1/1分周比

• PCLKD ( PCKD[2:0] ) : 0  0  0  →  1/1分周比

となります．
すなわち，Arduino UNO R4のデフォルトでは最大周波数であるシステムクロック(ICLK)は48MHz，A/D変換(PCLKC)は64MHzで動作していることがわかります．
これで，「Arduino UNO R3のようにArduino UNO R4のA/D変換のクロックの分周比を変えて高速化できないの?という質問」に関する回答は，「分周比の変更によるA/D変換の高速化は不可能」と言えます．

レジスタ全体の値の読み取り方法はドット(.)をアロー(->)に変えて，先頭に「R_」を付けることでした．
ですが，毎回，全体を読み取るのは面倒です．
そのために，例えば，SYSTEM.SCKDIVCRのICK[2:0]に直接アクセスできる方法(おそらく，共用体)があります．

1. 「ドット(.)」を「アロー演算子->」に変える
   「SYSTEM->SCKDIVCR」

2. 先頭に「R_」を付ける  (ここまでは全体と変わらない)
   「R_SYSTEM->SCKDIVCR」

3. 最後尾に「_b」を付ける
   「R_SYSTEM->SCKDIVCR_b」

4. 最後尾にドットとアクセスしたい要素を指定 (例，ICKの場合)
   「R_SYSTEM->SCKDIVCR_b.ICK」

実際に，Arduino IDEでSCKDIVCRレジスタの各要素の値を読み取るソースコードを書いてみましょう:

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
  Serial.print("ICK (BIN) = ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.ICK, BIN);

  Serial.print("PCKA (BIN) = ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.PCKA, BIN);

  Serial.print("PCKB (BIN) = ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.PCKB, BIN);

  Serial.print("PCKC (BIN) = ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.PCKC, BIN);

  Serial.print("PCKD (BIN) = ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.PCKD, BIN);

  Serial.print("FCK (BIN) = ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.FCK, BIN);
}
void loop() {
  // put your main code here, to run repeatedly:
}

結果は

• ICK (BIN) = 0

• PCKA (BIN) = 0

• PCKB (BIN) = 1

• PCKC (BIN) = 0

• PCKD (BIN) = 0

• FCK (BIN) = 1

のため，もちろん，前の結果と変わりませんね．
(※2進数表記では001は1と表示され，000は0と表示されます．また，010は10と表示されます．)

もう読み込みはいいから，SCKDIVCRレジスタを変えたいんだ!ってなってきますね．
ちょっとフライングして，
R_SYSTEM->SCKDIVCR_b.PCKC = 0b010;
のようにA/D変換のクロックの分周比を1/4に変えてしまえ，ということ試した方，残念ながら，このままでは，レジスタの値を変更することができません．
プロテクトレジスタによってレジスタの値は書き換え禁止になっています．
そこで，次はプロテクトレジスタの値を書き換えて，レジスタの書き換えを許可する方法を紹介します．

ルネサス社製のマイコンRA4M1の「Renesas RA4M1グループ ユーザーズマニュアル ハードウェア編」のp.262 「12.2.1 プロテクトレジスタ(PRCR)」を見てみましょう．
まず，重要なのはアドレスです:

• SYSTEM.PRCR 4001 E3FEh

次に，SYSTEM.PRCRの要素は以下の4つがあります:

• PRC0 : 1ビット
  用途: クロック発生回路関連レジスタへの書き込み許可または禁止
  使い方: 0: 書き込み禁止， 1: 書き込み許可

• PRC1 : 1ビット
  用途: 低消費電力モードおよびバッテリバックアップ機能関連のレジスタへの書き込み許可または禁止
  使い方: 0: 書き込み禁止， 1: 書き込み許可

• PRC3 : 1ビット
  用途: LVD関連レジスタへの書き込み許可または禁止
  使い方: 0: 書き込み禁止， 1: 書き込み許可

• PRKEY : 8ビット
  用途: PRCRレジスタへの書き込みを制御
  使い方: PRCRレジスタを書き換える場合，上位8ビット(PRKEY)にA5 (※HEX)，下位8ビット(PRC0, PRC1, PRC3)に目的の値とし，計16ビット単位で書く

ということで，A/D変換のクロックの分周比を調整するPCLKC (PCKC)を書き換えたい場合，PRC0 を1に書き換える必要があります．
しかし，SYSTEM.PRCRの要素PRC0を0から1に変えるためのプログラム
R_SYSTEM->PRCR_b.PRC0 = 0b1;
を書いても書き換わりません! (->やR_，_bについては，もう大丈夫ですよね?)
その理由がPRKEYにあります．
PRKEYはPRC0, PRC1, PRC3を書き換えるための鍵であり，SYSTEM.PRCRに対して，PRKEYを含めた全16ビットを同時に書き換えなければ，PRC0, PRC1, PRC3を書き換えることができません．
書き換えたい場合，b15からb8に位置するPRKEYは16進数でA5にせよ，と仕様書には書かれています．
その上，b7からb4は2進数で0000であるため，16進数で「0xA50」までは確定しています．
最後のb3からb0の4ビットでPRC0, PRC1, PRC3のフラグを調整します．

• PRC0のみ1, PRC1と PRC3は0 → 2進数で0001 → 16進数で1→ 0xA501

• PRC0は0, PRC1のみ1, PRC3は0 → 2進数で0010 → 16進数で2 → 0xA502

• PRC0とPRC1は0,  PRC3のみ1 → 2進数で1000 → 16進数で8 → 0xA508

• PRC0，PRC1,  PRC3のすべてを0 → 2進数で0000 → 16進数で0 → 0xA500

• PRC0，PRC1,  PRC3のすべてを1 → 2進数で1011 → 16進数でB → 0xA50B

のように，b3からb0のビットのフラグを調整すれば，プロテクトレジスタのどの要素のフラグを1にするのか指示できます．
もちろん，必要な要素のみフラグを1にして下さい．
また，必ず，使い終わったらプロテクトレジスタのフラグを0にしましょう．

1. 書き換えたいレジスタに対応するプロテクトレジスタのフラグを1にする

2. 書き換えたいレジスタの値を書き換える

3. 使い終わったらプロテクトレジスタのフラグを0にする(0xA500)

実際に，Arduino IDEからプロテクトレジスタを操作するプログラム例を書いてみましょう:

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);

  Serial.print("Defalt: PRC0 (BIN) = ");
  Serial.println(R_SYSTEM->PRCR_b.PRC0, BIN);

  R_SYSTEM->PRCR = 0xA501;  // PRC0のみ1に変える

  Serial.print("Update? PRC0 (BIN) = ");
  Serial.println(R_SYSTEM->PRCR_b.PRC0, BIN);

  R_SYSTEM->PRCR = 0xA500;  // PRC0,PRC1,PRC3を0に変える

  Serial.print("Finish: PRC0 (BIN) = ");
  Serial.println(R_SYSTEM->PRCR_b.PRC0, BIN);
}

void loop() {
  // put your main code here, to run repeatedly:
}

この結果は下記のようになるはずです:

Defalt: PRC0 (BIN) = 0
Update? PRC0 (BIN) = 1
Finish: PRC0 (BIN) = 0

これによって，プロテクトレジスタの要素PRC0のフラグを1にして，クロック周波数の分数比を調整する準備ができました．

いよいよ，次にA/D変換のクロック周波数の分数比を変えてみましょう．

ここまでちゃんと読んだ方は，「Arduino IDEにてArduino UNO R4のA/D変換のクロック周波数の分周比を1/2にするプログラムを書け」という問題を出しても，きっと解けるはずです．
もし，時間に余裕があるなら，↑を復習しながら取り組んでみましょう!

正解:
R_SYSTEM->PRCR = 0xA501;
R_SYSTEM->SCKDIVCR_b.PCKC = 0b001;
R_SYSTEM->PRCR = 0xA500;

復習も兼ねて1行ずつ解説していきましょう．

まず，
  R_SYSTEM->PRCR = 0xA501;
は，プロテクトレジスタ(PRCR)のPRC0を1にする，という意味でしたね．
特に「PRC0を1にする」というのは，「クロック発生回路関連レジスタへの書き込みを許可する」という意味でした．
これで，クロック発生回路関連レジスタへ書き込みができるようになりました．

続いて
  R_SYSTEM->SCKDIVCR_b.PCKC = 0b001;
です．
これは，SCKDIVCRレジスタの要素PCKCに0 0 1をセットする，という意味でしたね．
「PCKCに0 0 1をセットする」というのは，「ADC14変換クロックである周辺モジュールクロックC（PCLKC）を2分周に設定する」しています．
例えば，応用として，PCLKCを0 1 0  にセットしたら，A/D変換のクロックの分数比を4分周に設定できましたね．

最後に，
  R_SYSTEM->PRCR = 0xA500;
は，プロテクトレジスタ(PRCR)のPRC0，PRC1,  PRC3をすべてを0にする，という意味でした．
すなわち，「レジスタの書き込みを禁止する」という意味になります．

実際にArduino IDEで書き換わっているか，確かめてみましょう:

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);

  Serial.print("Default PCKC: ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.PCKC, BIN);

  R_SYSTEM->PRCR = 0xA501;
  R_SYSTEM->SCKDIVCR_b.PCKC = 0b001;
  R_SYSTEM->PRCR = 0xA500;

  Serial.print("Update PCKC: ");
  Serial.println(R_SYSTEM->SCKDIVCR_b.PCKC, BIN);
}

void loop() {
  // put your main code here, to run repeatedly:
}

これで，A/D変換のクロックの分周比が1/2に変わったはずです．
しかし，これでは，本当に遅くなったのか実感がわきませんね...
そこで，次は，実際に分周比を変えることでanalogReadの速度が遅くなることを確認してみましょう!

ここでも前節と同様にArduino UNO R4のArduino APIのanalogReadでは，シリアル通信やDACなどは行われていない，すなわち，analogReadではPCLKA, PCLKB, PCLKD, FCLKは影響がないと仮定して話を進めます．
本節では前節の測定結果を用いて，2変数(x, y)の連立方程式に帰着し，クロック数を推察します．(特に，前節で一旦忘れてもらったEquationに関係します!)

まず，1回のanalogReadにかかる時間は

システムクロック(ICLK)による演算時間 + A/D変換のクロック(PCLKC)による演算時間

と書けます．
次に未知変数として

• x : システムクロック(ICLK)を用いたクロック数

• y : A/D変換のクロック(PCLKC)を用いたクロック数

とします．
そのとき，

システムクロック(ICLK)を用いた演算時間 = 1クロックの時間*x

となります．
さらにシステムクロック(ICLK)は48MHzで固定しているため1クロックあたりの時間[μs]は1/48( = 1/48000000*1000*1000)  となります．
よって，

システムクロック(ICLK)を用いた演算時間[μs] = 1/48[μs] * x[回] 

となります．

同様に，「A/D変換のクロック(PCLKC)を用いた演算時間」も考えていきます．
但し，A/D変換のクロック(PCLKC)は分周比を変化させているため，

• f[MHz] : 分周したA/D変換のクロック周波数

とします．
すなわち，PCLKCを1分周にしたときはf=64 [MHz]を意味し，2分周にしたときはf=32[MHz]を意味します．
このとき，A/D変換のクロック(PCLKC)を利用した場合の1クロックあたりの時間[μs]は1/f [μs] (= 1/(f*1000*1000)*1000*1000)となります．
よって，

A/D変換のクロック(PCLKC)を用いた演算時間[μs] = 1/f[μs] * y[回] 

となります．

以上から，PCLKCをn分周にしたとき，方程式

1/48[μs] * x[回]  + 1/f[μs] * y[回] =  1回のanalogReadにかかる時間[μs]

が得られます．

例えば，PCLKCを1分周(f=64MHz)にしたとき，前節の測定結果から1回のanalogReadにかかる時間は21.39 [μs] であったことを利用すると

1/48[μs] * x[回]  + 1/64[μs] * y[回] = 21.39 [μs]

という方程式になります．

以上を他の分周比の場合もまとめると7つの方程式

• 1分周(64MHz):  1/48[μs] * x[回]  + 1/64[μs] * y[回] = 21.39 [μs]

• 2分周(32MHz):  1/48[μs] * x[回]  + 1/32[μs] * y[回] = 23.78 [μs]

• 4分周(16MHz):  1/48[μs] * x[回]  + 1/16[μs] * y[回] = 28.37 [μs]

• 8分周(8MHz):  1/48[μs] * x[回]  + 1/8[μs] * y[回] = 37.35 [μs]

• 16分周(4MHz):  1/48[μs] * x[回]  + 1/4[μs] * y[回] = 55.42 [μs]

• 32分周(2MHz):  1/48[μs] * x[回]  + 1/2[μs] * y[回] = 91.41 [μs]

• 64分周(1MHz):  1/48[μs] * x[回]  + 1/1[μs] * y[回] = 164.06 [μs]

を得られます．
これが，前節の結果で表示していたEquationの意味です．
未知変数が2変数であるため，上記の内，任意の2つ方程式を選んで連立方程式として解けば，「システムクロック(ICLK)を用いたクロック数x」と「A/D変換のクロック(PCLKC)を用いたクロック数y」が推察できます．

方程式の数が7つあり，そこから2つ組み合わせを選ぶため，全部で21通りあります．
21通りに対し，解は得るプログラムをMatlabで書くと下記のようになります:

A_all = [
    1/48, 1/64;
    1/48, 1/32;
    1/48, 1/16;
    1/48, 1/8;
    1/48, 1/4;
    1/48, 1/2;
    1/48, 1/1;
    ];

b_all = [
    21.39;
    23.78;
    28.37;
    37.35;
    55.42;
    91.41;
    164.06;
    ];

A = zeros(2,2);
b = zeros(2,1);
res = zeros(2,15);

k = 1;
for i = 1:6
    for j = i+1:7
        A(1,:) = A_all(i,:);
        A(2,:) = A_all(j,:);
        b(1) = b_all(i);
        b(2) = b_all(j);
        x = A\b;
        res(:,k) = x;
        k = k + 1;
    end
end

上記に対し，箱ひげ図は

boxchart(res(1,:)')

や

boxchart(res(2,:)')

で書くことができます．
実際に全てのパターンで解いた解は下記のようになります:

• 1分周と2分周の解 x = 912.0000  152.9600

• 1分周と4分周の解 x = 915.0400  148.9067

• 1分周と8分周の解 x = 917.2800  145.9200

• 1分周と16分周の解 x = 917.8240  145.1947

• 1分周と32分周の解 x = 918.3019  144.5574

• 1分周と64分周の解 x = 918.0190  144.9346

• 2分周と4分周の解 x = 921.1200  146.8800

• 2分周と8分周の解 x = 924.3200  144.7467

• 2分周と16分周の解 x = 924.4800  144.6400

• 2分周と32分周の解 x = 925.0240  144.2773

• 2分周と64分周の解 x = 924.2323  144.8052

• 4分周と8分周の解 x = 930.7200  143.6800

• 4分周と16分周の解 x = 928.9600  144.2667

• 4分周と32分周の解 x = 929.4857  144.0914

• 4分周と64分周の解 x = 927.5520  144.7360

• 8分周と16分周の解 x = 925.4400  144.5600

• 8分周と32分周の解 x = 927.8400  144.1600

• 8分周と64分周の解 x = 923.9314  144.8114

• 16分周と32分周の解 x = 932.6400  143.9600

• 16分周と64分周の解 x = 921.9200  144.8533

• 32分周と64分周の解 x = 900.4800  145.3000

上記の結果や「図. analogReadのクロック数の推察」から

• システムクロック(ICLK)を用いたクロック数: 917～929 クロック

• A/D変換のクロック(PCLKC)を用いたクロック数: 144～146 クロック

くらいなのではないか?と推察することができます．(あくまで，推察であり，正しさは保証されていませんのでご注意ください．)

この結果から，デフォルト (ICLK: 48MHz, PCLKC: 64MHz) のanalogReadの1回あたりの時間の割り振りは，

• ICLK: 19.1[μs] ～ 19.35[μs]

• PCLKC: 2.25[μs] ～ 2.28[μs]

• 合計: 21.35[μs] ～ 21.63[μs]

くらいと計算できます．

このことから，Arduino APIのanalogReadはA/D変換にかかる時間よりも，ほかの処理にかかる時間が主要なのではないか?と考えられます．
そこで，次はanalogReadのソースコードを解析し，analogReadでシステムクロックを使う時間を減らし，A/D変換に特化させる方法を考えていきましょう!